Alapfogalmak

Kernel: kiértékel és tárolja a kiszámított értékeket

notebook - ok ( *.nb file): munkafüzet

cellák (jobb oldalon zárójelezés): a notebook alapeleme; hierarcikus felépítés; csoportosítás

paletták

Fontosabb menü utasítások

File: Open, New, Close, Save (Save as), ...

Edit: Copy, Paste, Find, ...

Cell menü

Kernel menü

Format (Style)

Help (F1): futtatható Mathematica alkalmazások

Cella típusok

Title, Subtitle, Subsubtitle

Section, Subsection, Subsubsection

Text

Input (InputForm, StandardForm, TraditionalForm)

Output

Képletek, parancsok beírása

Formátumok:

InputForm: alfanumerikus, speciális karaktereket és grafikus matematikai szimbólumokat nem tartalmaz, speciális zárójelezés, Courier Bold betűtipus

StandardForm: az InputForm alakját és logikáját követi, grafikus matematikai szimbólumokat tartalmaz

TraditionalForm: a klasszikus matematikai jelölésrendszert követi (Times New Roman Bold)

Kis - és nagybetűk különböznek

Zárójelezés:

( ) 	- algebrai csoportosítás

f [ ] 	- függvények

{} 	- listák megadása

a[[i]] 	- listák elemei

Parancsok futtatása: Shift-Enter

Alapvető műveletek és operátorok

Algebrai műveletek

+ : összeadás

- : kivonás

*  vagy space : szorzás

/ : osztás

^ : hatványozás

! : faktoriális

() : csoportosítás

Példák

2+8;

2+8

2 (7-3)

Néhány beépített állandó

E ; e

Pi; π

Infinity; ∞

I; i

Példák

E^2

Infinity^(-1)

(E^(-∞))

Megjegyzések:

2 és 2. mást jelent!

2 : szimbolikus (egész érték)

2.: numerikus közelítés

Kifejezés numerikus közelítő értéke: N[kif]

Példák

(Sqrt[2])

(Sqrt[2.])

N[Pi]

N[Pi,100]

Függvények és szimbolikus számolások

Beépített elemi függvények Input formában

a*x + b

a*x^2 + b*x + c

x^a

Sqrt[x]

Sin[x],Cos[x],Tan[x],Cot[x]

Exp[x], E^x

Log[x],Log[a,x]

Abs[x]

Max[x,y], Min[x,y]

Példák

Sin[x]^2+Cos[x]^2

Sin[Pi]^2+Cos[Pi]^2

Log[10,100]

Max[x^2,-1]

Algebrai átalakítások

Expand[ ] :  polinomiális alakra hoz

Factor[ ] : szorzattá alakít

Simplify[ ], FullSimplify[ ] : egyszerűsít

Példák

Simplify[Sin[x]^2+Cos[x]^2]

Simplify[Max[x^2,-1]]

Factor[x^4-1]

Expand[(x-4)^2+(x+3)^3]

FullSimplify[Sin[x]+Cos[x],Trig->True]

Változók és értékadások

azonnali értékadás: lhs = rhs

késleltetett  értékadás: lhs := rhs

Példák

expr=Sin[x]^2+Cos[x]^2

expr:=Sin[x]^2+Cos[x]^2

expr

Értékek törlése, visszahozása

Clear[]

Remove[]

Használó által definiált függvények

Egyváltozós függvények

f[x_] = Sin[x] + Cos[x]

f[y]

f[0]

g[x]=(x^2)

g[2]

Többváltozós függvények

ff[x_, y_] := Sin[x] + Cos[y]

ff[Pi,-Pi]

Függvényábrázolás

Egyváltozós függvény ábrázolása: Plot

Ábrázolás alapbeállításokkal

Plot[Tan[x],{x,-2π,2π}]

Több függvény ábrázolása

Plot[{Sin[x],Cos[x]},{x,0,2Pi}]

Fontosabb speciális beállítások: más rajzolóműveleteknél is használhatók!

A tengelyek arányának beállítása

Az x tengely kétszer hosszabb mint az y tengely

Plot[Tan[x],{x,-2π,2π},AspectRatio->1/2]

Az x tengely és az y tengely léptéke azonos

Plot[Tan[x],{x,-2π,2π},AspectRatio->Automatic]

Az ábrázolási tartomány beállítása

Plot[Tan[x],{x,-2π,2π},PlotRange->{-3,3}]

Plot[Tan[x],{x,-2π,2π},PlotRange->{{-Pi,Pi},{-3,3}}]

Tengelyek címkézése

Plot[Tan[x],{x,-2π,2π},AxesLabel->{x,y},AspectRatio->Automatic,PlotRange->{-5,5}]

Logaritmikus ábrázolások

LogPlot[E^x,{x,-2,3},GridLines->Automatic]

LogLogPlot[(x^(1/3)),{x,0.001,5},GridLines->Automatic]

LogLinearPlot[Log[x],{x,0.001,3},GridLines->Automatic]

Kétváltozós függvény ábrázolása

Grafikon a 3D térben: Plot3D

Alaputasítás

F[x_,y_]:=x^2-y^2
x1=y1=-1;
x2=y2=1;
dx=dy=0.1;

Plot3D[F[x,y],{x,x1,x2},{y,y1,y2}]

Plot3D[F[x,y],{x,x1,x2},{y,y1,y2},BoxRatios->Automatic]

ContourPlot

ContourPlot[F[x,y],{x,x1,x2},{y,y1,y2},Mesh->True,FrameLabel->{x,y}]

DensityPlot

DensityPlot[F[x,y],{x,x1,x2},{y,y1,y2},PlotPoints->50]

Adathalmazok és ábrázolásuk: ListPlot

ListPlot[Table[Sin[x],{x,0,2Pi, Pi/12}]]

Egyenletek megoldása

Egyenletek megadása : left-hand-side == right-hand-side

= érték megadás

== egyenlet

=== az egyenlőség ellenőrzése

Egyszerű egyenlet:

Clear[a, b, c, x];
eqn1 = a x^2 + b x + c == 1

Egyenlet rendszer:

eqnlist={2 (x^2)+y==1,x+2y==2}

Vektoriális egyenlet rendszer:

fvec={(x^2)+y,x-4 y};
val={1,1};

fvec==val

Formális megoldás: Solve

a=1;b=4;c=2;

Solve[eqn1,x]

Solve[eqnlist,{x,y}]

Solve[fvec==val,{x,y}]

Polinomiális egyenletek numerikus megoldása: NSolve

Clear[f]
eqn=((x^7)-(x^6)+(x^3)-3 (x^2)-2 x-1==0);

Solve[eqn,x]

NSolve[eqn,x]

Egyenlet megoldásainak közelítése: FindRoot

f1[x_]:=(E^x);
f2[x_]:=4 Sin[x];

Solve[f1[x]==f2[x],x]

Plot[{f1[x], f2[x]}, {x, 0, π/2}]

xinit = {0.37, 4.};
FindRoot[f1[x] == f2[x], {x, xinit[[1]]}]
FindRoot[f1[x] == f2[x], {x, xinit[[2]]}]

Table[FindRoot[f1[x] == f2[x], {x, xinit[[i]]}], {i, 1, Length[xinit]}]

Map[FindRoot[f1[x] == f2[x], {x, #}] &, xinit]

Egyszerű interaktív vizsgálatok: Manipulate

Manipulate[Plot[Sin[x(1+a x)],{x,0,6}],{a,0,2}]

A kalkulus gyakran használt függvényei

Határérték: Limit

Limit[(1/n),n->Infinity]

Limit[(Tan[x]),x->Pi/2]

Plot[Tan[x],{x,-Pi/2,Pi}]

Limit[Tan[x],x->Pi/2, Direction->1]

Limit[Tan[x],x->Pi/2, Direction->-1]

Deriválás

f'; D[f] -- az f függvény első deriváltja

f'[x]; Derivative[f][x] -- f első deriváltja x - ben

Derivative[n1, n2, ...][f] -- f ni-szeres deriváltja az i-edik változójában

D[expr,x]; (∂_x) expr -- az expr kifejezés első deriváltja x-ben

D[expr,{x,n}]; (∂_({x,n}))expr	 --  az expr n-edik deriváltja x-ben

D[expr,x1,x2,x3,...] -- az expr parciális deriváltja az x1, x2, ...-ben

D[expr, {x1, n1}, {x2, n2}, ...]; (∂_({x1,n1},{x2,n2}..,))expr -- az expr n1, n2, ...-szeres parciális deriváltja az x1, x2, ...-ben

Példák

f[x_]:=x^5-4 x^3+3 x^2-5

f'[x]

D[f[x],x]

f''[x]

g[x_,y_]:=(x^2) (y^3)-Sin[x y];

Derivative[1,0][g]

Derivative[1,0][g][x,y]

Derivative[1,1][g][x,y]

Integrálás

Integrate[expr, x] -- expr x szerinti integrálja

∫f[x]dx

Integrate[expr, {x, x1, x2}] -- expr határozott integrálja [x1, x2]-n

(∫_x0^x1)f[x]dx

Példák

Integrate[Sin[x], x]

∫Sin[x] \[DifferentialD]x

Integrate[Sin[x], {x, 0, Pi/2}]

(∫_0^(π/2))Sin[x]\[DifferentialD]x