Manipulate[
DynamicModule[{ppts,spts,plt},
Grid[{{
(* Profile curve *)
Labeled[LocatorPane[Dynamic[pts],
Dynamic[Graphics[{BSplineCurve[ppts,SplineDegree->2],Dashed,Orange,Line[ppts]},PlotRange->{{0,2},{0,4}},Frame->True,FrameTicks->None,GridLines->Automatic,GridLinesStyle->LightGray,AspectRatio->Automatic,ImageSize->{100,250}]],LocatorAutoCreate->{2,∞}],Style["Profil görbe","Label"],Top],
Dynamic[
ppts=pts;
spts=Table[Append[#,Last[p]]&/@(First[p] cpts),{p,ppts}];
plt=Graphics3D[{
FaceForm[frontc,backc],Opacity[op],Specularity[White,spec],
BSplineSurface[spts,SplineClosed->{False,True},SplineDegree->2,SplineKnots->{Automatic,k},SplineWeights->Table[w,{Length[pts]}]]},
PlotRange->All,BoxRatios->Automatic,ImageSize->{300,300},Boxed->False,SphericalRegion->True]]
},{" ",Button["Nagy méret",CreateWindow[DocumentNotebook[Dynamic[Show[plt,ImageSize->{600,600}]]],WindowSize->{650,650}]]}}]
],
Style["Tervezzünk forgástesteket",Large, Bold],
Style["http://demonstrations.wolfram.com/PottersWheel/ felhasználásával"],
Delimiter,
"None"->{{pts,{{0,0},{0.1,0.4},{2,0.6},{0.2,1},{0.2,2.5},{0,3}}},{0,0},{1,1},ControlType->None},
Row[{
Column[{Control[{{sorted,False},ControlType->None}],
Control[{{mesh,False},ControlType->None}]},Right],
Spacer[20],
Column[{Control[{{frontc,Yellow,"Külső szín"},Yellow,ImageSize->Tiny}],
Control[{{backc,Blue,"Belső szín"},Blue,ImageSize->Tiny}]},Right],
Spacer[20],
Column[{Control[{{op,1,"Átlátszóság"},0,1,ImageSize->Tiny}],Control[{{spec,50,"Fényesség"},0,100,ImageSize->Tiny}]}]
}],
Delimiter,Style["Új mintapont / pont megszüntetése: Alt-Klikk"],
Initialization:>(cpts={{0,-1},{-1,-1},{-1,1},{0,1},{1,1},{1,-1}};
w={1,.5,.5,1,.5,.5};
k={0,0,0,1/4,1/2,1/2,3/4,1};)
]